Logische Funktionen

Inhalte

# Kategorie Logisch

Diese Kategorie enthält die Logischen Funktionen.

### Handhabung nicht logischer Argumente in logischen Funktionen

- Null(0) ist gleichwertig zu FALSCH und alle anderen Zahlen sind gleichwertig zu WAHR.

- Leere Zellen und Text in Zellen werden ignoriert.

- Wenn alle Argumente ignoriert werden, wird der Fehler #WERT ausgelöst.

- Wenn ein Argument auf Text verweist (nicht Text in einer Zelle), wird der Fehler #WERT ausgelöst.

- Fehler in Argumenten führen zu einem Fehler.

Auf diesen Befehl zugreifen …

Wählen Sie Einfügen – Funktion… – Kategorie: Logisch

### ISTNV

Ergibt WAHR, wenn eine Zelle den Fehlerwert #NV (Wert nicht verfügbar) enthält.

Wenn ein Fehler auftritt, ergibt die Funktion FALSCH.

#### Syntax

ISTNV(Wert)

Wert ist der Wert oder ein Ausdruck, der zu prüfen ist.

#### Beispiel

=ISTNV(D3) ergibt FALSCH.

### WENNFEHLER

Gibt den Wert zurück, wenn die Zelle keinen Fehlerwert enthält, oder den alternativen Wert, wenn sie einen Fehlerwert enthält.

Diese Funktion ist seit LibreOffice 4.0 verfügbar.

#### Syntax

WENNFEHLER(Wert; Alternativer Wert)

Wert ist der Wert oder Ausdruck, der zurückgegeben werden soll, wenn er ungleich ist oder zu einem Fehler führt.

Alternativer Wert ist der Wert oder Ausdruck, der zurückgegeben werden soll, wenn der Ausdruck oder Wert für Wert gleich ist oder zu einem Fehler führt.

#### Beispiel

WENNFEHLER(C8;C9), wobei C8 =1/0 enthält, ergibt den Wert aus C9, da 1/0 nicht berechnet werden kann.

WENNFEHLER(C8;C9), wobei C8 13 enthält, ergibt 13, den Wert von C8, da 13 kein Fehler ist.

## WENNS

WENNS ist eine mehrfache Funktion WENN.

## SCHALTER

SCHALTER vergleicht Ausdruck mit Wert_1 bis Wert_n und gibt das Ergebnis zurück, das zu dem ersten Wert gehört, dem Ausdruck entspricht. Wenn es keine Übereinstimmung gibt und Standardergebnis angegeben ist, wird dies zurückgegeben.

## FALSCH

Ergibt den Wahrheitswert FALSCH. Die Funktion FALSCH() benötigt keine Argumente und ergibt immer den logischen Wert FALSCH.

#### Syntax

FALSCH()

#### Beispiel

=FALSCH() ergibt FALSCH

=NICHT(FALSCH()) ergibt WAHR

## NICHT

Komplementiert (invertiert) einen logischen Wert.

#### Syntax

NICHT(LogischerWert)

LogischerWert ist ein umzukehrender Wert.

#### Beispiel

=NICHT(A). Wenn A=WAHR, dann ergibt NICHT(A) FALSCH.

## ODER

Ergibt WAHR, wenn mindestens ein Argument WAHR ist. Haben alle Argumente den Wert FALSCH, ergibt diese Funktion FALSCH.

Die Argumente sind entweder selbst logische Ausdrücke (WAHR, 1<5, 2+3=7, B8<10), die Wahrheitswerte zurückliefern, oder Matrizen (A1:C3), die Wahrheitswerte enthalten.

#### Syntax

ODER(Logischer Wert 1 [; Logischer Wert 2 [; … [; Logischer Wert 255]]])

Logischer Wert 1; Logischer Wert 2; …; Logischer Wert 255 sind logische Werte oder Verweise auf Zellen oder Zellbereiche mit logischen Werten.

Diese Funktion ignoriert jeden Text oder jede leere Zelle innerhalb eines Datenbereichs. Wenn Sie falsche Ergebnisse dieser Funktion vermuten, suchen Sie nach Text in den Datenbereichen. Um Textinhalte in einem Datenbereich hervorzuheben, verwenden Sie die Funktion Werte hervorheben.

#### Beispiel

Die Einträge 12<11; 13>22 und 45=45 sollen auf Ihre logischen Werte hin überprüft werden.

=ODER(12<11;13>22;45=45) ergibt WAHR.

=ODER(FALSCH();WAHR()) ergibt WAHR.

Die Matrixformel {=ODER(B1:B10;C1:C10)} ergibt einen eindimensionalen Wert FALSCH, wenn alle Komponenten von B1:B10 und C1:C10 FALSCH sind. Der obige Matrixausdruck erzeugt nicht das logische ODER pro Element und erzeugt daher keine Matrix logischer Werte. Um ein logisches ODER von Matrizen pro Element zu berechnen, verwenden Sie den Operator + im Matrixkontext. Geben Sie im Beispiel {=B1:B10+C1:C10} ein.

## UND

Ergibt WAHR, wenn alle Argumente WAHR sind. Hat eines der Argumente den Wert FALSCH, ergibt diese Funktion FALSCH.

Die Argumente sind entweder selbst logische Ausdrücke (WAHR, 1<5, 2+3=7, B8<10), die Wahrheitswerte zurückliefern, oder Matrizen (A1:C3), die Wahrheitswerte enthalten.

#### Syntax

UND(Logischer Wert 1 [; Logischer Wert 2 [; … [; Logischer Wert 255]]])

Logischer Wert 1; Logischer Wert 2; …; Logischer Wert 255 sind logische Werte oder Verweise auf Zellen oder Zellbereiche mit logischen Werten.

Diese Funktion ignoriert jeden Text oder jede leere Zelle innerhalb eines Datenbereichs. Wenn Sie falsche Ergebnisse dieser Funktion vermuten, suchen Sie nach Text in den Datenbereichen. Um Textinhalte in einem Datenbereich hervorzuheben, verwenden Sie die Funktion Werte hervorheben.

#### Beispiel

Die Wahrheitswerte der Einträge 12<13; 14>12 und 7<6 sollen geprüft werden:

=UND(12<13;14>12;7<6) ergibt FALSCH.

=UND(FALSCH();WAHR()) ergibt FALSCH.

Die Matrixformel {=UND(B1:B10;C1:C10)} ergibt einen eindimensionalen Wert WAHR, wenn alle Komponenten von B1:B10 und C1:C10 WAHR sind. Der obige Matrixausdruck erzeugt nicht das logische UND pro Element und erzeugt daher keine Matrix logischer Werte. Um ein logisches UND von Matrizen pro Element zu berechnen, verwenden Sie den Operator * im Matrixkontext. Geben Sie im Beispiel {=B1:B10*C1:C10} ein.

## WAHR

Der Wahrheitswert WAHR wird gesetzt. Die Funktion WAHR() benötigt keine Argumente und ergibt immer den logischen Wert WAHR.

#### Syntax

WAHR()

#### Beispiel

Wenn A=WAHR und B=FALSCH ergeben sich folgende Beispiele:

=UND(A;B) ergibt FALSCH

=ODER(A;B) ergibt WAHR

=NICHT(UND(A;B)) ergibt WAHR

## WENN

Legt die durchzuführende Wahrheitsprüfung fest.

#### Syntax

WENN(Prüfung [; [DannWert] [; [SonstWert]]])

Prüfung ist ein beliebiger Wert oder Ausdruck, der WAHR oder FALSCH sein kann.

DannWert (optional) ist der Wert, der zurückgegeben wird, wenn die logische Prüfung WAHR ist.

SonstWert (optional) ist der Wert, der zurückgegeben wird, wenn die logische Prüfung FALSCH ist.

In LibreOffice Calc-Funktionen dürfen Parameter, die als „optional“ gekennzeichnet sind, nur dann ausgelassen werden, wenn ihnen kein weiterer Parameter mehr folgt. So können Sie beispielsweise in einer Funktion mit vier Parametern, von denen die letzten beiden als „optional“ gekennzeichnet sind, den Parameter 4 oder die Parameter 3 und 4 auslassen, jedoch nicht den Parameter 3 allein.

#### Beispiel

=WENN(A1>5;100;"zu klein") – Wenn der Wert in A1 größer als 5 ist, wird der Wert 100 wird zurückgegeben; anderenfalls wird der Text zu klein zurückgegeben.

=WENN(A1>5;;"zu klein") – Wenn der Wert in A1 größer als 5 ist, wird der Wert 0 zurückgegeben, da leere Parameter als 0 behandelt werden; anderenfalls wird der Text zu klein zurückgegeben.

=WENN(A1>5;100;) – Wenn der Wert in A1 kleiner als 5 ist, wird der Wert 0 zurückgegeben, weil der leere SonstWert als 0 interpretiert wird; anderenfalls wird 100 zurückgegeben.

## XODER

Ergibt WAHR, wenn eine ungerade Anzahl von Argumenten WAHR liefert.

Die Argumente sind entweder selbst logische Ausdrücke (WAHR, 1<5, 2+3=7, B8<10), die Wahrheitswerte zurückliefern, oder Matrizen (A1:C3), die Wahrheitswerte enthalten.

Diese Funktion ist seit LibreOffice 4.0 verfügbar.

#### Syntax

XODER(Logischer Wert 1 [; Logischer Wert 2 [; … [; Logischer Wert 255]]])

Logischer Wert 1; Logischer Wert 2; …; Logischer Wert 255 sind logische Werte oder Verweise auf Zellen oder Zellbereiche mit logischen Werten.

#### Beispiel

=XODER(WAHR();WAHR()) ergibt FALSCH.

=XODER(WAHR();WAHR();WAHR()) ergibt WAHR.

=XODER(FALSCH();WAHR()) ergibt WAHR.

Verwandte Themen

Funktionen nach Kategorie

Bitte unterstützen Sie uns!